Steady-State Temperature Distribution in Conducting Square

F[T2_,T4_,m_,y_]:=4*(1/Pi)*(1/(2m+1))*(1/Sinh[(2m+1)*Pi])*(T2*Sinh[(2m+1)*Pi*y]+T4*Sinh[(2m+1)*Pi*(1-y)])

G[T1_,T3_,m_,x_]:=4*(1/Pi)*(1/(2m+1))*(1/Sinh[(2m+1)*Pi])*(T1*Sinh[(2m+1)*Pi*(1-x)]+T3*Sinh[(2m+1)*Pi*x])

uu[T1_,T2_,T3_,T4_,x_,y_]:=NSum[(F[T2,T4,m,y]*Sin[(2m+1)*Pi*x]+G[T1,T3,m,x]*Sin[(2m+1)*Pi*y]),{m,0,10}]

u222[T1_,T2_,T3_,T4_]:=ContourPlot[uu[T1,T2,T3,T4,x,y],{x,0,1},{y,0,1},Contours->10,ColorFunction->"TemperatureMap",ContourShading->Automatic,ContourLabels->If[T1==T2==T3==T4,False,Function[{x,y,z},Text[Framed[z],{x,y},Background->White]]],ImageSize->{400,380}]

Manipulate[
u222[T1,T2,T3,T4],
Style["temperatures (°C)",Bold],
{{T1,20,"left"},-300,300,Appearance->"Labeled"},
{{T2,0,"top"},-300,300,Appearance->"Labeled"},
{{T3,0,"right"},-300,300,Appearance->"Labeled"},
{{T4,0,"bottom"},-300,300,Appearance->"Labeled"},
SaveDefinitions->True,TrackedSymbols->True,AutorunSequencing->{1,4},SynchronousUpdating->False]

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Steady-State Temperature Distribution in Conducting Square" from The Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/SteadyStateTemperatureDistributionInConductingSquare/

Contributed by: Hernan Vivas

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© The Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »